REM Disable the Escape key
*ESC OFF

REM Set up a simple error handler
ON ERROR PROCerror

REM Make 2 MB of RAM available for this program
HIMEM = LOMEM + 2 * &100000

REM Prevent the program window being resized
SYS "GetWindowLong", @hwnd%, -16 TO S%
SYS "SetWindowLong", @hwnd%, -16, S% AND NOT &50000
SYS "SetWindowPos", @hwnd%, 0, 0, 0, 0, 0, 32+7
SYS "SetWindowPos", @hwnd%, -1, 0, 0, 0, 0, 3

REM Set up display mode 8 (640x512 pixels)
MODE 8
OFF

REM Install and initialise GFXLIB
INSTALL @lib$ + "GFXLIB2"
PROCInitGFXLIB

REM Install the external GFXLIB module 'PlotShadow'
INSTALL @lib$ + "GFXLIB_modules\PlotShadow"
PROCInitModule

REM Load the ball bitmap (64x64 BMP file)
ballBmp = FNLoadBMP( @lib$ + "GFXLIB_media\ball1_64x64x8.BMP", 0 )

REM We'll have 40 balls bouncing around...
numBalls = 40

REM Set up a structure to hold the position and velocity
REM information for each ball
DIM ball{( numBalls ) x, y, dx, dy}

REM Define the initial positions and velocities of the balls
FOR I = 0 TO numBalls
  ball{(I)}.x = RND(640 - 64)
  ball{(I)}.y = RND(512 - 64)
  ball{(I)}.dx = 1 + 5*RND(1)
  ball{(I)}.dy = 1 + 5*RND(1)
NEXT I

REM Switch off the automatic window refresh
*REFRESH OFF

REM Here's our main loop...
REPEAT

  REM Clear the background (fill it with orange)
  SYS GFXLIB_Clr%, dispVars{}, FNrgb(230, 180, 20)

  REM Draw the ball shadows, then the actual balls,
  REM then update their positions
  FOR I = 1 TO numBalls

    SYS GFXLIB_PlotShadow%, dispVars{}, ballBmp, 64, 64, \
    \ ball{(I)}.x-12, ball{(I)}.y-12, 0

    SYS GFXLIB_Plot%, dispVars{}, ballBmp, 64, 64, \
    \ ball{(I)}.x, ball{(I)}.y

    ball{(I)}.x += ball{(I)}.dx
    ball{(I)}.y += ball{(I)}.dy

    IF ball{(I)}.x < 0 OR ball{(I)}.x > 640-64 THEN
      ball{(I)}.dx *= -1
    ENDIF

    IF ball{(I)}.y < 0 OR ball{(I)}.y > 512-64 THEN
      ball{(I)}.dy *= -1
    ENDIF

  NEXT I

  REM Render to the program window
  PROCdisplay

UNTIL FALSE
END

DEF PROCerror
*REFRESH ON
ON
PRINT '" ";
PRINT REPORT$ + " at line "; ERL;
REPEAT
  WAIT 10
UNTIL FALSE
ENDPROC